1 files changed, 50 insertions, 0 deletions
diff --git a/util/mkelfImage/kunzip_src/arch/alpha/lib/kunzip.lds b/util/mkelfImage/kunzip_src/arch/alpha/lib/kunzip.lds
new file mode 100644
index 0000000000..ed632686a8
--- /dev/null
+++ b/util/mkelfImage/kunzip_src/arch/alpha/lib/kunzip.lds
@@ -0,0 +1,50 @@
+PAGE_SIZE = 65536;
+BASIC_ALIGN = 8;
+OUTPUT_FORMAT("elf64-alpha")
+ENTRY(__start)
+SECTIONS
+{
+	. = PAGE_SIZE;
+	_start = .;
+	/*
+	 * First we place the code and read only data (typically const declared).
+	 * This get placed in rom.
+	 */
+	.text : {
+		_text = .;
+		*(.text)
+		_etext = .;
+		_rodata = .;
+		*(.rodata);
+		_erodata = .;
+	}
+	/* Global data */
+	.data : {
+		_data = .;
+		*(.data) 
+		CONSTRUCTORS
+		*(.got)
+		*(.sdata)
+		_edata = .;
+	}
+	
+	/* Important align _bss so bss may be zeroed with quadword access */
+	. = ALIGN(BASIC_ALIGN);
+	.bss : {
+		_bss = .;
+		*(.sbss) 
+		*(.scommon)
+		*(.bss)
+		*(COMMON)
+		*(.heap)
+		*(.stack)
+		/* Important align _ebss so bss may be zeroed with quadword access */
+		. = ALIGN(BASIC_ALIGN);
+		_ebss = .;
+	}
+	_end = .;
+
+	/DISCARD/ : {
+		*(*)
+	}
+}