diff options
| author | jljusten <jljusten@6f19259b-4bc3-4df7-8a09-765794883524> | 2012-08-15 00:03:25 +0000 |
|---|---|---|
| committer | jljusten <jljusten@6f19259b-4bc3-4df7-8a09-765794883524> | 2012-08-15 00:03:25 +0000 |
| commit | e148512e5132e38accf2fe8188a9bdf9d1de02d8 (patch) | |
| tree | d49269a1679a3e0c29f07fb79b4124b745bc7b42 /EmulatorPkg/Sec/X64 | |
| parent | 33efdf51b0f123259dec0bfcff49af189b46c411 (diff) | |
| download | edk2-platforms-e148512e5132e38accf2fe8188a9bdf9d1de02d8.tar.xz | |
EmulatorPkg: Fix Visual Studio build for IA32 & X64
This code is untested since there is currently no 'host' component
for Win32/Win64.
Contributed-under: TianoCore Contribution Agreement 1.0
Signed-off-by: Jordan Justen <jordan.l.justen@intel.com>
git-svn-id: https://edk2.svn.sourceforge.net/svnroot/edk2/trunk/edk2@13633 6f19259b-4bc3-4df7-8a09-765794883524
Diffstat (limited to 'EmulatorPkg/Sec/X64')
| -rw-r--r-- | EmulatorPkg/Sec/X64/SwitchRam.asm | 76 |
1 files changed, 76 insertions, 0 deletions
diff --git a/EmulatorPkg/Sec/X64/SwitchRam.asm b/EmulatorPkg/Sec/X64/SwitchRam.asm new file mode 100644 index 0000000000..d1a7b943fd --- /dev/null +++ b/EmulatorPkg/Sec/X64/SwitchRam.asm @@ -0,0 +1,76 @@ +;------------------------------------------------------------------------------
+;
+; Copyright (c) 2006 - 2012, Intel Corporation. All rights reserved.<BR>
+; Portitions copyright (c) 2011, Apple Inc. All rights reserved.
+; This program and the accompanying materials
+; are licensed and made available under the terms and conditions of the BSD License
+; which accompanies this distribution. The full text of the license may be found at
+; http://opensource.org/licenses/bsd-license.php.
+;
+; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
+; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
+;
+;------------------------------------------------------------------------------
+
+EXTERN CopyMem:PROC
+EXTERN ZeroMem:PROC
+
+ .code
+
+;------------------------------------------------------------------------------
+; EFI_STATUS
+; EFIAPI
+; SecTemporaryRamSupport (
+; IN CONST EFI_PEI_SERVICES **PeiServices, // %rcx
+; IN EFI_PHYSICAL_ADDRESS TemporaryMemoryBase, // %rdx
+; IN EFI_PHYSICAL_ADDRESS PermanentMemoryBase, // %r8
+; IN UINTN CopySize // %r9
+; )
+;------------------------------------------------------------------------------
+SecTemporaryRamSupport PROC
+ ; Adjust callers %rbp to account for stack move
+ sub rbp, rdx ; Calc offset of %rbp in Temp Memory
+ add rbp, r8 ; add in permanent base to offset
+
+ push rbp ; stack frame is for the debugger
+ mov rbp, rsp
+
+ push rdx ; Save TemporaryMemoryBase
+ push r8 ; Save PermanentMemoryBase
+ push r9 ; Save CopySize
+
+ ;
+ ; Copy all of temp RAM to permanent memory, including stack
+ ;
+ ; CopyMem (PermanentMemoryBase, TemporaryMemoryBase, CopySize);
+ ; %rcx, %rdx, %r8
+ mov rcx, r8 ; Shift arguments
+ mov r8, r9
+ sub rsp, 028h ; Allocate register spill area & 16-byte align stack
+ call CopyMem
+ ; Temp mem stack now copied to permanent location. %esp still in temp memory
+ add rsp, 028h
+
+ pop r9 ; CopySize (old stack)
+ pop r8 ; PermanentMemoryBase (old stack)
+ pop rdx ; TemporaryMemoryBase (old stack)
+
+ mov rcx, rsp ; Move to new stack
+ sub rcx, rdx ; Calc offset of stack in Temp Memory
+ add rcx, r8 ; Calc PermanentMemoryBase address
+ mov rsp, rcx ; Update stack
+ ; Stack now points to permanent memory
+
+ ; ZeroMem (TemporaryMemoryBase /* rcx */, CopySize /* rdx */);
+ mov rcx, rdx
+ mov rdx, r9
+ sub rsp, 028h ; Allocate register spill area & 16-byte align stack
+ call ZeroMem
+ add rsp, 028h
+
+ ; This data comes off the NEW stack
+ pop rbp
+ ret
+SecTemporaryRamSupport ENDP
+
+ END
|