From bb89ec1a7ec2f8d35033df9e47b3604925da3bd3 Mon Sep 17 00:00:00 2001
From: jljusten <jljusten@6f19259b-4bc3-4df7-8a09-765794883524>
Date: Tue, 28 Jun 2011 16:47:23 +0000
Subject: InOsEmuPkg: Rename package to EmulatorPkg & Sec to Host

* Rename InOsEmuPkg to EmulatorPkg
* Rename Unix/Sec to Unix/Host

Signed-off-by: jljusten
Reviewed-by: andrewfish
Reviewed-by: geekboy15a

git-svn-id: https://edk2.svn.sourceforge.net/svnroot/edk2/trunk/edk2@11918 6f19259b-4bc3-4df7-8a09-765794883524
---
 EmulatorPkg/Unix/GdbRun | 79 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)
 create mode 100644 EmulatorPkg/Unix/GdbRun

(limited to 'EmulatorPkg/Unix/GdbRun')

diff --git a/EmulatorPkg/Unix/GdbRun b/EmulatorPkg/Unix/GdbRun
new file mode 100644
index 0000000000..428e655631
--- /dev/null
+++ b/EmulatorPkg/Unix/GdbRun
@@ -0,0 +1,79 @@
+## @file
+# GDB startup script
+#
+# Copyright (c) 2011, Intel Corporation. All rights reserved.<BR>
+#
+# This program and the accompanying materials
+# are licensed and made available under the terms and conditions of the BSD License
+# which accompanies this distribution. The full text of the license may be found at
+# http://opensource.org/licenses/bsd-license.php
+#
+# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
+# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
+#
+##
+
+#
+# Gdb will set $_exitcode when the program exits.  Pre-init it to an unlikely
+# return value.
+#
+set $_exitcode = 42
+
+#
+# Gdb will call hook-stop on each break.  Check to see if $_exitcode was
+# changed from the value we pre-initialized it to.  If so, the program
+# had exited, so gdb should now quit.
+#
+define hook-stop
+  if $_exitcode != 42
+    quit
+  else
+    source SecMain.gdb
+  end
+end
+
+#
+# We keep track of the number of symbol files we have loaded via gdb
+# scripts in the $SymbolFilesAdded variable
+#
+set $SymbolFileChangesCount = 0
+
+#
+# This macro adds a symbols file for gdb
+#
+# @param  $arg0 - Symbol file changes number
+# @param  $arg1 - Symbol file name
+# @param  $arg2 - Image address
+#
+define AddFirmwareSymbolFile
+  if $SymbolFileChangesCount < $arg0
+    add-symbol-file $arg1 $arg2
+    set $SymbolFileChangesCount = $arg0
+  end
+end
+
+#
+# This macro removes a symbols file for gdb
+#
+# @param  $arg0 - Symbol file changes number
+# @param  $arg1 - Symbol file name
+#
+define RemoveFirmwareSymbolFile
+  if $SymbolFileChangesCount < $arg0
+    #
+    # Currently there is not a method to remove a single symbol file
+    #
+    set $SymbolFileChangesCount = $arg0
+  end
+end
+
+if gInXcode == 1
+  # in Xcode the program is already runing. Issuing a run command 
+  # will cause a fatal debugger error. The break point sciprt that
+  # is used to source this script sets gInCode to 1. 
+else
+  #
+  # Start the program running
+  #
+  run
+end
-- 
cgit v1.2.3