ext: Add pybind rev f4b81b3

Change-Id: I52e4fc9ebf2f59da57d8cf8f3e37cc79598c2f5f
Signed-off-by: Andreas Sandberg <andreas.sandberg@arm.com>
Reviewed-by: Andreas Hansson <andreas.hansson@arm.com>
Reviewed-by: Curtis Dunham <curtis.dunham@arm.com>
Reviewed-on: https://gem5-review.googlesource.com/2229
Reviewed-by: Tony Gutierrez <anthony.gutierrez@amd.com>
Reviewed-by: Jason Lowe-Power <jason@lowepower.com>
Reviewed-by: Pierre-Yves Péneau <pierre-yves.peneau@lirmm.fr>

1 files changed, 159 insertions, 0 deletions

diff --git a/ext/pybind11/tests/CMakeLists.txt b/ext/pybind11/tests/CMakeLists.txt
new file mode 100644
index 000000000..27cb65291
--- /dev/null
+++ b/ext/pybind11/tests/CMakeLists.txt
@@ -0,0 +1,159 @@
+if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
+  message(STATUS "Setting tests build type to MinSizeRel as none was specified")
+  set(CMAKE_BUILD_TYPE MinSizeRel CACHE STRING "Choose the type of build." FORCE)
+  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
+    "MinSizeRel" "RelWithDebInfo")
+endif()
+
+# Full set of test files (you can override these; see below)
+set(PYBIND11_TEST_FILES
+  test_alias_initialization.cpp
+  test_buffers.cpp
+  test_callbacks.cpp
+  test_chrono.cpp
+  test_class_args.cpp
+  test_constants_and_functions.cpp
+  test_copy_move_policies.cpp
+  test_docstring_options.cpp
+  test_eigen.cpp
+  test_enum.cpp
+  test_eval.cpp
+  test_exceptions.cpp
+  test_inheritance.cpp
+  test_issues.cpp
+  test_keep_alive.cpp
+  test_kwargs_and_defaults.cpp
+  test_methods_and_attributes.cpp
+  test_modules.cpp
+  test_multiple_inheritance.cpp
+  test_numpy_array.cpp
+  test_numpy_dtypes.cpp
+  test_numpy_vectorize.cpp
+  test_opaque_types.cpp
+  test_operator_overloading.cpp
+  test_pickling.cpp
+  test_python_types.cpp
+  test_sequences_and_iterators.cpp
+  test_smart_ptr.cpp
+  test_stl_binders.cpp
+  test_virtual_functions.cpp
+)
+
+# Invoking cmake with something like:
+#     cmake -DPYBIND11_TEST_OVERRIDE="test_issues.cpp;test_picking.cpp" ..
+# lets you override the tests that get compiled and run.  You can restore to all tests with:
+#     cmake -DPYBIND11_TEST_OVERRIDE= ..
+if (PYBIND11_TEST_OVERRIDE)
+  set(PYBIND11_TEST_FILES ${PYBIND11_TEST_OVERRIDE})
+endif()
+
+string(REPLACE ".cpp" ".py" PYBIND11_PYTEST_FILES "${PYBIND11_TEST_FILES}")
+
+# Check if Eigen is available; if not, remove from PYBIND11_TEST_FILES (but
+# keep it in PYBIND11_PYTEST_FILES, so that we get the "eigen is not installed"
+# skip message).
+list(FIND PYBIND11_TEST_FILES test_eigen.cpp PYBIND11_TEST_FILES_EIGEN_I)
+if(PYBIND11_TEST_FILES_EIGEN_I GREATER -1)
+  find_package(Eigen3 QUIET)
+
+  if(EIGEN3_FOUND)
+    message(STATUS "Building tests with Eigen v${EIGEN3_VERSION}")
+  else()
+    list(REMOVE_AT PYBIND11_TEST_FILES ${PYBIND11_TEST_FILES_EIGEN_I})
+    message(STATUS "Building tests WITHOUT Eigen")
+  endif()
+endif()
+
+# Create the binding library
+pybind11_add_module(pybind11_tests pybind11_tests.cpp
+  ${PYBIND11_TEST_FILES} ${PYBIND11_HEADERS})
+
+pybind11_enable_warnings(pybind11_tests)
+
+if(EIGEN3_FOUND)
+  target_include_directories(pybind11_tests PRIVATE ${EIGEN3_INCLUDE_DIR})
+  target_compile_definitions(pybind11_tests PRIVATE -DPYBIND11_TEST_EIGEN)
+endif()
+
+set(testdir ${PROJECT_SOURCE_DIR}/tests)
+
+# Always write the output file directly into the 'tests' directory (even on MSVC)
+if(NOT CMAKE_LIBRARY_OUTPUT_DIRECTORY)
+  set_target_properties(pybind11_tests PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${testdir})
+  foreach(config ${CMAKE_CONFIGURATION_TYPES})
+    string(TOUPPER ${config} config)
+    set_target_properties(pybind11_tests PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${config} ${testdir})
+  endforeach()
+endif()
+
+# Make sure pytest is found or produce a fatal error
+if(NOT PYBIND11_PYTEST_FOUND)
+  execute_process(COMMAND ${PYTHON_EXECUTABLE} -m pytest --version --noconftest OUTPUT_QUIET ERROR_QUIET
+                  RESULT_VARIABLE PYBIND11_EXEC_PYTHON_ERR)
+  if(PYBIND11_EXEC_PYTHON_ERR)
+    message(FATAL_ERROR "Running the tests requires pytest.  Please install it manually (try: ${PYTHON_EXECUTABLE} -m pip install pytest)")
+  endif()
+  set(PYBIND11_PYTEST_FOUND TRUE CACHE INTERNAL "")
+endif()
+
+# A single command to compile and run the tests
+add_custom_target(pytest COMMAND ${PYTHON_EXECUTABLE} -m pytest -rws ${PYBIND11_PYTEST_FILES}
+                  DEPENDS pybind11_tests WORKING_DIRECTORY ${testdir})
+
+if(PYBIND11_TEST_OVERRIDE)
+  add_custom_command(TARGET pytest POST_BUILD
+    COMMAND ${CMAKE_COMMAND} -E echo "Note: not all tests run: -DPYBIND11_TEST_OVERRIDE is in effect")
+endif()
+
+# test use of installation
+if(PYBIND11_INSTALL)
+  # 2.8.12 needed for test_installed_module
+  # 3.0 needed for interface library for test_installed_target
+  # 3.1 needed for cmake -E env for testing
+  if(NOT CMAKE_VERSION VERSION_LESS 3.1)
+    add_custom_target(test_installed_target
+      COMMAND ${CMAKE_COMMAND}
+              "-DCMAKE_INSTALL_PREFIX=${PROJECT_BINARY_DIR}/test_install"
+              -P "${PROJECT_BINARY_DIR}/cmake_install.cmake"
+      COMMAND ${CMAKE_CTEST_COMMAND}
+              --build-and-test "${CMAKE_CURRENT_SOURCE_DIR}/test_installed_target"
+                               "${CMAKE_CURRENT_BINARY_DIR}/test_installed_target"
+              --build-noclean
+              --build-generator ${CMAKE_GENERATOR}
+              $<$<BOOL:${CMAKE_GENERATOR_PLATFORM}>:--build-generator-platform> ${CMAKE_GENERATOR_PLATFORM}
+              --build-makeprogram ${CMAKE_MAKE_PROGRAM}
+              --build-target check
+              --build-options "-DCMAKE_PREFIX_PATH=${PROJECT_BINARY_DIR}/test_install"
+                              "-DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}"
+                              "-DPYTHON_EXECUTABLE=${PYTHON_EXECUTABLE}"
+                              "-DPYBIND11_CPP_STANDARD=${PYBIND11_CPP_STANDARD}"
+    )
+    add_custom_target(test_installed_module
+      COMMAND ${CMAKE_COMMAND}
+              "-DCMAKE_INSTALL_PREFIX=${PROJECT_BINARY_DIR}/test_install"
+              -P "${PROJECT_BINARY_DIR}/cmake_install.cmake"
+      COMMAND ${CMAKE_CTEST_COMMAND}
+              --build-and-test "${CMAKE_CURRENT_SOURCE_DIR}/test_installed_module"
+                               "${CMAKE_CURRENT_BINARY_DIR}/test_installed_module"
+              --build-noclean
+              --build-generator ${CMAKE_GENERATOR}
+              $<$<BOOL:${CMAKE_GENERATOR_PLATFORM}>:--build-generator-platform> ${CMAKE_GENERATOR_PLATFORM}
+              --build-makeprogram ${CMAKE_MAKE_PROGRAM}
+              --build-target check
+              --build-options "-DCMAKE_PREFIX_PATH=${PROJECT_BINARY_DIR}/test_install"
+                              "-DCMAKE_CXX_COMPILER=${CMAKE_CXX_COMPILER}"
+                              "-DPYTHON_EXECUTABLE=${PYTHON_EXECUTABLE}"
+                              "-DPYBIND11_CPP_STANDARD=${PYBIND11_CPP_STANDARD}"
+    )
+  else()
+    add_custom_target(test_installed_target)
+    add_custom_target(test_installed_module)
+  endif()
+  add_custom_target(test_install)
+  add_dependencies(test_install test_installed_target test_installed_module)
+endif()
+
+# And another to show the .so size and, if a previous size, compare it:
+add_custom_command(TARGET pybind11_tests POST_BUILD
+    COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_SOURCE_DIR}/tools/libsize.py
+        $<TARGET_FILE:pybind11_tests> ${CMAKE_CURRENT_BINARY_DIR}/sosize-$<TARGET_FILE_NAME:pybind11_tests>.txt)