1 files changed, 90 insertions, 0 deletions
diff --git a/EDK/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/DivU64x64Remainder.asm b/EDK/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/DivU64x64Remainder.asm
new file mode 100644
index 0000000..eb16032
--- /dev/null
+++ b/EDK/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/DivU64x64Remainder.asm
@@ -0,0 +1,90 @@
+; Copyright (c) 2004, Intel Corporation                                                         
+; All rights reserved. This program and the accompanying materials                          
+; are licensed and made available under the terms and conditions of the BSD License         
+; which accompanies this distribution.  The full text of the license may be found at        
+; http://opensource.org/licenses/bsd-license.php                                            
+;                                                                                           
+; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,                     
+; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.    
+;
+; Module Name:
+;
+;   DivU64x64Remainder.asm
+;
+; Abstract:
+;
+;   Calculate the quotient of a 64-bit integer by a 64-bit integer and returns
+;   both the quotient and the remainder
+;
+;------------------------------------------------------------------------------
+
+    .386
+    .model  flat,C
+    .code
+
+EXTERN  InternalMathDivRemU64x32:PROC
+
+;------------------------------------------------------------------------------
+; UINT64
+; EFIAPI
+; InternalMathDivRemU64x64 (
+;   IN      UINT64                    Dividend,
+;   IN      UINT64                    Divisor,
+;   OUT     UINT64                    *Remainder    OPTIONAL
+;   );
+;------------------------------------------------------------------------------
+InternalMathDivRemU64x64    PROC
+    mov     ecx, [esp + 16]
+    test    ecx, ecx
+    jnz     _@DivRemU64x64              ; call _@DivRemU64x64 if Divisor > 2^32
+    mov     ecx, [esp + 20]
+    jecxz   @F
+    and     dword ptr [ecx + 4], 0
+    mov     [esp + 16], ecx
+@@:
+    jmp     InternalMathDivRemU64x32
+InternalMathDivRemU64x64    ENDP
+
+_@DivRemU64x64  PROC    USES    ebx esi edi
+    mov     edx, dword ptr [esp + 20]
+    mov     eax, dword ptr [esp + 16]   ; edx:eax <- dividend
+    mov     edi, edx
+    mov     esi, eax                    ; edi:esi <- dividend
+    mov     ebx, dword ptr [esp + 24]   ; ecx:ebx <- divisor
+@@:
+    shr     edx, 1
+    rcr     eax, 1
+    shrd    ebx, ecx, 1
+    shr     ecx, 1
+    jnz     @B
+    div     ebx
+    mov     ebx, eax                    ; ebx <- quotient
+    mov     ecx, [esp + 28]
+    mul     dword ptr [esp + 24]
+    imul    ecx, ebx
+    add     edx, ecx
+    mov     ecx, dword ptr [esp + 32]
+    jc      @TooLarge                   ; product > 2^64
+    cmp     edi, edx                    ; compare high 32 bits
+    ja      @Correct
+    jb      @TooLarge                   ; product > dividend
+    cmp     esi, eax
+    jae     @Correct                    ; product <= dividend
+@TooLarge:
+    dec     ebx                         ; adjust quotient by -1
+    jecxz   @Return                     ; return if Remainder == NULL
+    sub     eax, dword ptr [esp + 24]
+    sbb     edx, dword ptr [esp + 28]
+@Correct:
+    jecxz   @Return
+    sub     esi, eax
+    sbb     edi, edx                    ; edi:esi <- remainder
+    mov     [ecx], esi
+    mov     [ecx + 4], edi
+@Return:
+    mov     eax, ebx                    ; eax <- quotient
+    xor     edx, edx
+    ret
+_@DivRemU64x64  ENDP
+
+    END