1 files changed, 66 insertions, 0 deletions
diff --git a/EDK/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/EnablePaging64.asm b/EDK/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/EnablePaging64.asm
new file mode 100644
index 0000000..ce30372
--- /dev/null
+++ b/EDK/Foundation/Library/EdkIIGlueLib/Library/BaseLib/Ia32/EnablePaging64.asm
@@ -0,0 +1,66 @@
+; Copyright (c) 2004, Intel Corporation                                                         
+; All rights reserved. This program and the accompanying materials                          
+; are licensed and made available under the terms and conditions of the BSD License         
+; which accompanies this distribution.  The full text of the license may be found at        
+; http://opensource.org/licenses/bsd-license.php                                            
+;                                                                                           
+; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,                     
+; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.    
+;
+; Module Name:
+;
+;   EnablePaging64.Asm
+;
+; Abstract:
+;
+;   AsmEnablePaging64 function
+;
+; Notes:
+;
+;------------------------------------------------------------------------------
+
+    .686p
+    .model  flat,C
+    .code
+
+;------------------------------------------------------------------------------
+; VOID
+; EFIAPI
+; InternalX86EnablePaging64 (
+;   IN      UINT16                    Cs,
+;   IN      UINT64                    EntryPoint,
+;   IN      UINT64                    Context1,  OPTIONAL
+;   IN      UINT64                    Context2,  OPTIONAL
+;   IN      UINT64                    NewStack
+;   );
+;------------------------------------------------------------------------------
+InternalX86EnablePaging64 PROC
+    cli
+    mov     [esp], @F                   ; offset for far retf, seg is the 1st arg
+    mov     eax, cr4
+    or      al, (1 SHL 5)
+    mov     cr4, eax                    ; enable PAE
+    mov     ecx, 0c0000080h
+    rdmsr
+    or      ah, 1                       ; set LME
+    wrmsr
+    mov     eax, cr0
+    bts     eax, 31
+    mov     cr0, eax                    ; enable paging
+    retf
+@@:                                     ; long mode starts here
+    DB      67h, 48h
+    mov     ebx, [esp]                  ; mov rbx, [esp]
+    DB      67h, 48h
+    mov     ecx, [esp + 8]              ; mov rcx, [esp + 8]
+    DB      67h, 48h
+    mov     edx, [esp + 10h]            ; mov rdx, [esp + 10h]
+    DB      67h, 48h
+    mov     esp, [esp + 18h]            ; mov rsp, [esp + 18h]
+    DB      48h
+    add     esp, -20h                   ; add rsp, -20h
+    call    ebx                         ; call rbx
+    jmp     $
+InternalX86EnablePaging64 ENDP
+
+    END